home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d6 / glazer.arc / CREDITCA.BAS < prev    next >
Encoding:
BASIC Source File  |  1988-10-08  |  1.4 KB  |  32 lines
  1. 100 'Credit Card ("CREDITCARD")
  2. 110 CLS
  3. 120 COLOR 0,15 : PRINT "Credit Card" : COLOR 15,0
  4. 130 DEFDBL A-Z
  5. 140 MONEYFMT$ = "$$##,###,###.##"
  6. 150 PRINT : PRINT
  7. 160 PRINT "Do not enter dollar signs or commas"
  8. 170 PRINT
  9. 180 INPUT "Monthly purchases: ", PURCHASES
  10. 190 INPUT "Cash discount (in percent): ", DISCOUNT
  11. 200 INPUT "Annual credit card fee: ", FEE
  12. 210 INPUT "Annual interest rate (in percent): ", AR
  13. 220 '     Find daily interest rate
  14. 230 DR = (1 + AR / 100) ^ (1/360) - 1
  15. 240 '     Find monthly interest rate
  16. 250 PR = (1 + AR / 100) ^ (1/12) - 1
  17. 260 '     Calculate present value of cash expenditures
  18. 270 FCASH = (1 - (1 + DR) ^  -360) * (1 - DISCOUNT / 100) / (30 * DR)
  19. 280 PVCASH = PURCHASES * FCASH
  20. 290 '     Calculate present value of credit card purchases
  21. 300 FCARD = ( (1 - (1 + PR) ^  -12) / PR) / (1 + PR)
  22. 310 PVCARD = FEE + PURCHASES * FCARD
  23. 320 '     Minimum monthly purchase to make credit card worthwhile
  24. 330 BREAKEVEN = FEE / (FCASH - FCARD)
  25. 340 PRINT
  26. 350 PRINT "Cash cost: "; TAB(30); USING MONEYFMT$; PVCASH
  27. 360 PRINT "Credit card cost: "; TAB(30); USING MONEYFMT$; PVCARD
  28. 370 PRINT "Breakeven charge: "; TAB(30);
  29. 380 IF BREAKEVEN >= 0 THEN PRINT USING MONEYFMT$; BREAKEVEN                                           ELSE PRINT SPC(10); "Never"
  30. 390 PRINT "Saving in using credit card: "; TAB(30); USING MONEYFMT$;                      PVCASH - PVCARD
  31. 400 END
  32.